Для выполнения этой задачи используется функция ЕСЛИ.

Столбец1	Столбец2	Формула	Описание
15000	9000	=Столбец1>Столбец2	Значение Столбец1 больше, чем значение Столбец2? (Да)
15000	9000	=ЕСЛИ(Столбец1<=Столбец2; "Да"; "Нет")	Значение Столбец1 меньше или равно значению Столбец2? (Нет)

Для получения результата, являющегося логическим значением («Да» или «Нет») используйте функции И, ИЛИ и НЕ.

Столбец1	Столбец2	Столбец3	Формула	Описание
15	9	8	=И(Столбец1>Столбец2; Столбец1<Столбец3)	15 больше 9 и меньше 8? (Нет)
15	9	8	=ИЛИ(Столбец1>Столбец2; Столбец1<Столбец3)	15 больше 9 или меньше 8? (Да)
15	9	8	=НЕ(Столбец1+Столбец2=24)	15 плюс 9 не равно 24? (Нет)

Для получения результата, являющегося другим вычислением или любым значением, кроме «Да» или «Нет», используйте функции ЕСЛИ, И и ИЛИ.

Столбец1	Столбец2	Столбец3	Формула	Описание
15	9	8	=ЕСЛИ(Столбец1=15; "Да"; "Нет")	Если значение Столбец1 равно 15, возвращается «ОК». (ОК)
15	9	8	=ЕСЛИ(И(Столбец1>Столбец2; Столбец1<Столбец3); "Да"; "Нет")	Если 15 больше 9 и меньше 8, возвращается «ОК». (Нет)
15	9	8	=ЕСЛИ(ИЛИ(Столбец1>Столбец2; Столбец1<Столбец3); "Да"; "Нет")	Если 15 больше 9 или меньше 8, возвращается «ОК». (ОК)

Для выполнения этой задачи используется функция ЕСЛИ.

Столбец1	Столбец2	Формула	Описание
10	10	=Столбец1-Столбец2	Из первого (0) числа вычитается второе
10	10	=ЕСЛИ(Столбец1-Столбец2;"";Столбец1-Столбец2)	Если значение равняется нулю, возвращается пустое значение (пустой столбец)
15	9	=ЕСЛИ(Столбец1-Столбец2;"-";Столбец1-Столбец2)	Возвращает «-», если ячейка содержит нулевое значение

Чтобы прибавить к дате определенное число дней, используйте оператор сложения (+). При выполнении операций с датами в качестве возвращаемого типа для вычисляемого столбца следует выбрать тип данных Дата и время.

Столбец1	Столбец2	Формула	Описание
09.06.2007	3	=Столбец1+Столбец2	Прибавляет 3 дня к дате 09.06.2007 (12.06.2007)
10.12.2008	54	=Столбец1+Столбец2	Прибавляет 54 дня к дате 10.12.2008 (02.02.2009)

Чтобы прибавить к дате число месяцев, воспользуйтесь функциями ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Столбец1	Столбец2	Формула	Описание
09.06.2007	3	=ДАТА(Год(Столбец1);МЕСЯЦ(Столбец1)+Столбец2;ДЕНЬ(Столбец1))	Прибавляет 3 месяца к дате 09.06.2007 (09.09.2007)
10.12.2008	25	=ДАТА(Год(Столбец1);МЕСЯЦ(Столбец1)+Столбец2;ДЕНЬ(Столбец1))	Прибавляет 25 месяцев к дате 10.12.2008 (10.01.2011)

Чтобы прибавить к дате число лет, воспользуйтесь функциями ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Столбец1	Столбец2	Формула	Описание
09.06.2007	3	=ДАТА(ГОД(Столбец1)+Столбец2;МЕСЯЦ(Столбец1);ДЕНЬ(Столбец1))	Прибавляет 3 года к дате 09.06.2007 (09.06.2010)
10.12.2008	25	=ДАТА(ГОД(Столбец1)+Столбец2;МЕСЯЦ(Столбец1);ДЕНЬ(Столбец1))	Прибавляет 25 лет к дате 10.12.2008 (10.12.2033)

Чтобы прибавить к дате сочетание дней, месяцев и лет, воспользуйтесь функциями ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Столбец1	Формула	Описание
09.06.2007	=ДАТА(ГОД(Столбец1)+3,МЕСЯЦ(Столбец1)+1,ДЕНЬ(Столбец1)+5)	Прибавляет 3 года, 1 месяц и 5 дней к дате 09.06.2007 (14.07.2010)
10.12.2008	=ДАТА(ГОД(Столбец1)+1;МЕСЯЦ(Столбец1)+7;ДЕНЬ(Столбец1)+5)	Прибавляет 1 год, 7 месяцев и 5 дней к дате 09.06.2007 (14.01.2009)

Для выполнения этой задачи используется функция РАЗНДАТ.

Столбец1	Столбец2	Формула	Описание
01-янв-1995	15-июн-1999	=РАЗНДАТ(Столбец1; Столбец2;"д")	Возвращает число дней между двумя датами (1626)
01-янв-1995	15-июн-1999	=РАЗНДАТ(Столбец1; Столбец2;"гм")	Возвращает число месяцев между датами, игнорируя год (5)
01-янв-1995	15-июн-1999	=РАЗНДАТ(Столбец1; Столбец2;"гд")	Возвращает число дней между датами, игнорируя год (165)

Для представления результата в стандартном формате времени (часы:минуты:секунды) используйте оператор вычитания (-) и функцию ТЕКСТ.

Чтобы этот способ сработал, количество часов не должно превышать 24, а количество минут и секунд не должно превышать 60.

Столбец1	Столбец2	Формула	Описание
09.06.2007 10:35	09.06.2007 15:30:00	=ТЕКСТ(Столбец2-Столбец1;"ч")	Количество часов между двумя значениями времени (4)
09.06.2007 10:35	09.06.2007 15:30:00	=ТЕКСТ(Столбец2-Столбец1;"ч:мм")	Количество часов и минут между двумя значениями времени (4:55)
09.06.2007 10:35	09.06.2007 15:30:00	=ТЕКСТ(Столбец2-Столбец1;"ч:мм:сс")	Количество часов, минут и секунд между двумя значениями времени (04:55:00)

Для представления результата с помощью одной единицы изменения времени используйте функцию ЦЕЛОЕ или функции ЧАС, МИНУТЫ и СЕКУНДЫ.

Столбец1	Столбец2	Формула	Описание
09.06.2007 10:35	10.06.2007 15:30:00	=ЦЕЛОЕ((Столбец2-Столбец1)*24)	Общее количество часов между двумя значениями времени (28)
09.06.2007 10:35	10.06.2007 15:30:00	=ЦЕЛОЕ((Столбец2-Столбец1)*1440)	Общее количество минут между двумя значениями времени (1735)
09.06.2007 10:35	10.06.2007 15:30:00	=ЦЕЛОЕ((Столбец2-Столбец1)*86400)	Общее количество секунд между двумя значениями времени (104100)
09.06.2007 10:35	10.06.2007 15:30:00	=ЧАС(Столбец2-Столбец1)	Количество часов между двумя значениями времени, если разница не превышает 24 (4)
09.06.2007 10:35	10.06.2007 15:30:00	=МИНУТЫ(Столбец2-Столбец1)	Количество минут между двумя значениями времени, если разница не превышает 60 (55)
09.06.2007 10:35	10.06.2007 15:30:00	=СЕКУНДЫ(Столбец2-Столбец1)	Количество секунд между двумя значениями времени, если разница не превышает 60 (0).

Для преобразования значения часов из стандартного формата времени в десятичное число используйте функцию ЦЕЛОЕ.

Столбец1	Формула	Описание
10:35:00	=(Столбец1-ЦЕЛОЕ(Столбец1))*24	Число часов со времени 0:00:00 (10,583333)
12:15:00	=(Столбец1-ЦЕЛОЕ(Столбец1))*24	Число часов со времени 0:00:00 (12,25)

Для преобразования значения часов из десятичного числа в стандартный формат (часы:минуты:секунды) используйте оператор деления и функцию ТЕКСТ.

Столбец1	Формула	Описание
10:5833	=ТЕКСТ(Столбец1/24; "ч:мм")	Число часов со времени 0:00 (10:35:00)
12:25:00	=ТЕКСТ(Столбец1/24; "ч:мм")	Число часов со времени 0:00 (12:15)

Слова «юлианская дата» иногда используются для ссылки на формат дат, представляющий сочетание текущего года и количества дней с начала года. Например, 1 января 2007 г. представляется как 2007001, а 31 декабря 2007 г. — как 2007356.

Юлианское представление дат также обычно используется в астрономии, где даты отсчитываются с 1 января 4713 года до н. э.

 Примечание.   Следует помнить, что этот формат не основан на юлианском календаре.

Для преобразования даты в юлианское представление используйте функции ТЕКСТ и ДАТАЗНАЧ.

Столбец1	Формула	Описание
23.06.2007	=ТЕКСТ(Столбец1;"гг")&ТЕКСТ((Столбец1-ДАТАЗНАЧ("1/1/"& ТЕКСТ(Столбец1;"гг"))+1);"000")	Дата в юлианском формате с двузначным значением года (07174)
23.06.2007	=ТЕКСТ(Столбец1;"гггг")&ТЕКСТ((Столбец1-ДАТАЗНАЧ("1/1/"&ТЕКСТ(Столбец1;"гг"))+1);"000")	Дата в юлианском формате с четырехзначным значением года (2007174)

Для преобразования даты в юлианский астрономический формат используйте константу 2415018,50.

Эта формула работает только с датами после 01.03.1901, если используется система отсчета дат с 1900 г.

Столбец1	Формула	Описание
23.06.2007	=Столбец1+2415018,50	Дата в юлианском формате, используемом в астрономии (2454274,50)

Для преобразования дат в текстовое представление дней недели используйте функции ТЕКСТ и ДЕНЬНЕД.

Столбец1	Формула	Описание
19-фев-2007	=ТЕКСТ(ДЕНЬНЕД(Столбец1); "дддд")	Вычисление дня недели для указанной даты и возврат его полного названия (понедельник)
3-янв-2008	=ТЕКСТ(ДЕНЬНЕД(Столбец1): "ддд")	Вычисление дня недели для указанной даты и возврат его сокращенного названия (Пн)

Для сложения чисел из двух или нескольких столбцов в строке используйте оператор сложения или функцию СУММ.

Столбец1	Столбец2	Столбец3	Формула	Описание
6	5	4	=Столбец1+Столбец2+Столбец3	Сумма значений из трех первых столбцов (15)
6	5	4	=СУММ(Столбец1;Столбец2;Столбец3)	Сумма значений из трех первых столбцов (15)
6	5	4	=СУММ(ЕСЛИ(Столбец1>Столбец2; Столбец1-Столбец2; 10); Столбец3)	Если значение Столбец1 больше, чем значение Столбец2, их разность прибавляется к значению Столбец3. В противном случае к значению Столбец3 прибавляется 10 (5)

Для выполнения этой задачи используйте оператор вычитания (-).

Столбец1	Столбец2	Столбец3	Формула	Описание
15000	9000	-8000	=Столбец1-Столбец2	Вычитание 9000 из 15000 (6000)
15000	9000	-8000	=СУММ(Столбец1; Столбец2; Столбец3)	Сумма значений из трех первых столбцов, включая отрицательные значения (16000)

Используйте операторы вычитания (-) и деления (/) с функцией ABS.

Столбец1	Столбец2	Формула	Описание
2342	2500	=(Столбец2-Столбец1)/ABS(Столбец1)	Изменение в процентах (6,75% или 0,06746)

Для выполнения этой задачи используйте оператор умножения (*) или функцию ПРОИЗВЕД.

Столбец1	Столбец2	Формула	Описание
5	2	=Столбец1*Столбец2	Умножение чисел в первых двух столбцах (10)
5	2	=ПРОИЗВЕД(Столбец1; Столбец2)	Умножение чисел в первых двух столбцах (10)
5	2	=ПРОИЗВЕД(Столбец1;Столбец2;2)	Умножение чисел в первых двух столбцах и числа 2 (20)

Для выполнения этой задачи используйте оператор деления (/).

Столбец1	Столбец2	Формула	Описание
15000	12	=Столбец1/Столбец2	Деление 15000 на 12 (1250)
15000	12	=(Столбец1+10000)/Столбец2	Сложение 15000 и 9000 и деление результата на 12 (2000)

Среднее значение также называется просто средним. Чтобы вычислить среднее значение чисел в нескольких столбцах, воспользуйтесь функцией СРЗНАЧ.

Столбец1	Столбец2	Столбец3	Формула	Описание
6	5	4	=СРЗНАЧ(Столбец1;Столбец2;Столбец3)	Среднее значение чисел в первых трех столбцах (5)
6	5	4	=СРЗНАЧ(ЕСЛИ(Столбец1>Столбец2; Столбец1-Столбец2; 10); Столбец3)	Если значение Столбец1 больше значения Столбец2, рассчитывается среднее для разности и значения Столбец3. В противном случае рассчитывается среднее для числа 10 и значения Столбец3 (2,5)

Медиана представляет собой значение середины упорядоченного множества чисел. Для вычисления медианы набора чисел используйте функцию МЕДИАНА.

A	B	C	D	E	F	Формула	Описание
10	7	9	27	0	4	=МЕДИАНА(A; B; C; D; E; F)	Медиана чисел в первых 6 столбцах (8)

Чтобы найти наименьшее или наибольшее число в нескольких столбцах, воспользуйтесь функциями МИН и МАКС.

Столбец1	Столбец2	Столбец3	Формула	Описание
10	7	9	=МИН(Столбец1; Столбец2; Столбец3)	Наименьшее число (7)
10	7	9	=МАКС(Столбец1; Столбец2; Столбец3)	Наибольшее число (10)

Для подсчета количества числовых значений используйте функцию СЧЕТ.

Столбец1	Столбец2	Столбец3	Формула	Описание
Яблоня		12.12.2007	=СЧЁТ(Столбец1; Столбец2; Столбец3)	Подсчет количества столбцов, содержащих числовые значения, включая значения даты и времени. Исключаются текстовые и пустые значения (1)
$12	#ДЕЛ/0!	1,01	=СЧЁТ(Столбец1; Столбец2; Столбец3)	Подсчет количества столбцов, содержащих числовые значения, с исключением ошибок и логических значений (2)

Для выполнения этой задачи используется оператор процента (%).

Столбец1	Столбец2	Формула	Описание
23	3%	=Столбец1*(1+5%)	Увеличение значения Столбец1 на 5% (24,15)
23	3%	=Столбец1*(1+Столбец2)	Увеличение значения Столбец1 на процентное значение Столбец2: 3% (23,69)
23	3%	=Столбец1*(1-Столбец2)	Уменьшение значения Столбец1 на процентное значение Столбец2: 3% (22,31)

Для выполнения этой задачи используется оператор возведения в степень (^) или функция СТЕПЕНЬ.

Столбец1	Столбец2	Формула	Описание
5	2	=Столбец1^Столбец2	Возведение числа 5 в квадрат (25)
5	3	=СТЕПЕНЬ(Столбец1; Столбец2)	Возведение числа 5 в куб (125)

Для округления чисел сверху используются функции ОКРУГЛВВЕРХ, НЕЧЁТ и ЧЁТН.

Столбец1	Формула	Описание
20,3	=ОКРУГЛВВЕРХ(Столбец1;0)	Округление числа 20,3 вверх до ближайшего целого (21)
-5,9	=ОКРУГЛВВЕРХ(Столбец1;0)	Округление числа -5,9 вверх (-6)
12,5493	=ОКРУГЛВВЕРХ(Столбец1;2)	Округление числа 12,5493 до второго знака после запятой (12,55)
20,3	=ЧЁТН(Столбец1)	Округление числа 20,3 вверх до ближайшего четного (22)
20,3	=НЕЧЁТ(Столбец1)	Округление числа 20,3 вверх до ближайшего нечетного (21)

Для округления чисел в нижнюю сторону используется функция ОКРУГЛВНИЗ.

Столбец1	Формула	Описание
20,3	=ОКРУГЛВНИЗ(Столбец1;0)	Округление числа 20,3 вниз до ближайшего целого (20)
-5,9	=ОКРУГЛВНИЗ(Столбец1;0)	Округление числа -5,9 до ближайшего меньшего целого (-5)
12,5493	=ОКРУГЛВНИЗ(Столбец1;2)	Округление числа 12,5493 до второго знака после запятой (12,54)

Для округления числа до ближайшего целого числа или дроби воспользуйтесь функцией ОКРУГЛ.

Столбец1	Формула	Описание
20,3	=ОКРУГЛ(Столбец1;0)	Округление числа 20,3 вниз, так как дробная часть меньше 0,5 (20)
5,9	=ОКРУГЛ(Столбец1;0)	Округление числа 5,9 вверх, так как дробная часть больше 0,5 (6)
-5,9	=ОКРУГЛ(Столбец1;0)	Округление числа -5,9 вниз, так как дробная часть меньше 0,5 (-6)
1,25	=ОКРУГЛ(Столбец1; 1)	Округление числа до одного знака после запятой. Поскольку округляемая часть составляет 0,05 или больше, число округляется вверх (результат: 1,3)
30,452	=ОКРУГЛ(Столбец1; 2)	Округление числа до двух знаков после запятой. Поскольку округляемая часть (0,002) меньше 0,005, число округляется вниз (результат: 30,45)

Для округления числа до значащей цифры больше 0 используйте функции ОКРУГЛ, ОКРУГЛВВЕРХ, ОКРУГЛВНИЗ, ЦЕЛОЕ и ДЛСТР.

Столбец1	Формула	Описание
5492820	=ОКРУГЛ(Столбец1;3-ДЛСТР(ЦЕЛОЕ(Столбец1)))	Округление числа до 3 значащих разрядов (5490000)
22230	=ОКРУГЛВНИЗ(Столбец1;3-ДЛСТР(ЦЕЛОЕ(Столбец1)))	Округление нижнего числа вниз до 3 значащих разрядов (22200)
5492820	=ОКРУГЛВВЕРХ(Столбец1; 5-ДЛСТР(ЦЕЛОЕ(Столбец1)))	Округление верхнего числа вверх до 5 значащих разрядов (5492900)

Для выполнения этой задачи используйте функции ПРОПИСН, СТРОЧН или ПРОПНАЧ.

Столбец1	Формула	Описание
иван Петров	=ПРОПИСН(Столбец1)	Переводит буквы в прописные (ИВАН ПЕТРОВ)
иван Петров	=СТРОЧН(Столбец1)	Переводит буквы в строчные (иван петров)
иван Петров	=ПРОПНАЧ(Столбец1)	Переводит первые буквы слов в прописные (Иван Петров)

Для выполнения этой задачи используйте оператор конкатенации (&) или функцию СЦЕПИТЬ.

Столбец1	Столбец2	Формула	Описание
Алексей	Ушаков	=Столбец1&Столбец2	Слияние двух строк (АлексейУшаков)
Алексей	Ушаков	=Столбец1&" "&Столбец2	Объединение двух строк с разделением их пробелом (Алексей Ушаков)
Алексей	Ушаков	=Столбец2&", "&Столбец1	Объединение двух строк с разделением их запятой и пробелом (Ушаков, Алексей)
Алексей	Ушаков	=СЦЕПИТЬ(Столбец2; ","; Столбец1)	Объединение двух строк с разделением их запятой (Ушаков,Алексей)

Для выполнения этой задачи используйте оператор конкатенации (&) и функции СЦЕПИТЬ и ТЕКСТ.

Столбец1	Столбец2	Формула	Описание
Еременко	28	=Столбец1&" продал "&Столбец2&" единиц."	Объединение содержимого ячеек в одну фразу (Еременко продал 28 единиц.)
Тихонов	40%	=Столбец1&" продал "&ТЕКСТ(Столбец2;"0%")&" от общего числа товаров."	Из содержимого составляется фраза (Тихонов продал 40% от общего числа товаров.)  Примечание.   Функция ТЕКСТ добавляет к строке отформатированное значение Столбец2 вместо исходного значения (0,4).
Еременко	28	=СЦЕПИТЬ(Столбец1;" продал ";Столбец2;" единиц.")	Объединение содержимого ячеек в одну фразу (Еременко продал 28 единиц.)

Для выполнения этой задачи используйте функцию ТЕКСТ и оператор конкатенации (&).

Столбец1	Столбец2	Формула	Описание
Дата выставления счета:	5-июн-2007	="Выставлен: "&ТЕКСТ(Столбец2; "д-ммм-гггг")	Объединение текста с датой (Выставлен: 5-Июн-2007)
Дата выставления счета:	5-июн-2007	=Столбец1&" "&ТЕКСТ(Столбец2; "ммм-дд-ггг")	Объединение текста и даты из разных столбцов (Дата выставления счета: 5-июн-2007)

Для сравнения двух столбцов или списка значений используются функции СОВПАД и ИЛИ.

Столбец1	Столбец2	Формула	Описание
БД122	БД123	=СОВПАД(Столбец1;Столбец2)	Сравнение содержимого двух первых столбцов (Нет)
БД122	БД123	=СОВПАД(Столбец1; "BD122")	Сравнение содержимого Столбец1 и строки «БД122» (Да)
БД122	БД123	=ИЛИ(СОВПАД("BD121"; Столбец1; Столбец2)	Сравнение строки «БД121» с содержимым первых двух столбцов (Нет)

Чтобы проверить, совпадает ли значение или часть значения столбца, с определенным текстом, используйте функции ЕСЛИ, НАЙТИ, ПОИСК и ЕЧИСЛО.

Столбец1	Формула	Описание
Егоров	=ЕСЛИ(Столбец1="Егоров"; "Да"; "Нет")	Проверка, содержит ли значение Столбец1 строку «Егоров» (Да)
Егоров	=ЕСЛИ(ЕЧИСЛО(НАЙТИ("в";Столбец1)); "Да"; "Нет")	Проверка значения Столбец1 на наличие буквы «в» (Да)
БД123	=ЕЧИСЛО(НАЙТИ("БД"; Столбец1))	Проверка, содержит ли Столбец1 строку «БД» (Да)

Для выполнения этой задачи используется функция СЧЁТЗ.

Столбец1	Столбец2	Столбец3	Формула	Описание
Продажи	19		=СЧЁТЗ(Столбец1; Столбец2)	Подсчет числа непустых столбцов (2)
Продажи	19		=СЧЁТЗ(Столбец1; Столбец2; Столбец3)	Подсчет числа непустых столбцов (2)

Для выполнения этой задачи используются функции ДЛСТР, ЛЕВСИМВ и ПРАВСИМВ.

Столбец1	Формула	Описание
Витамин A	=ЛЕВСИМВ(Столбец1;ДЛСТР(Столбец1)-2)	Возвращаются 7 знаков (9-2), начиная слева (Витамин)
Витамин B1	=ПРАВСИМВ(Столбец1; ДЛСТР(Столбец1)-8)	Возвращаются 2 знака (10-8), начиная справа (B1)

Для выполнения этой задачи используется функция СЖПРОБЕЛЫ.

Столбец1	Формула	Описание
Привет!	=СЖПРОБЕЛЫ(Столбец1)	Удаление пробелов из начала и конца значения (Привет!)

Для выполнения этой задачи используется функция ПОВТОР.

Формула	Описание
=ПОВТОР("."; 3)	Повторение точки (.) 3 раза (...)
=ПОВТОР("-";10)	Повторение дефиса (-) 10 раз (----------)

Чтобы отобразить дефис, значение #Н/Д или НД вместо значения ошибки, воспользуйтесь функцией ЕОШИБКА.

Столбец1	Столбец2	Формула	Описание
10	0	=Столбец1/Столбец2	Ошибка (#ДЕЛ/0!)
10	0	=ЕСЛИ(ЕОШИБКА(Столбец1/Столбец2);"НД";Столбец1/Столбец2)	Возвращает значение НД, если ячейка содержит значение ошибки.
10	0	=ЕСЛИ(ЕОШИБКА(Столбец1/Столбец2);"-";Столбец1/Столбец2)	Возвращает дефис, если ячейка содержит значение ошибки.